8 votos

Es posible interpretar los coeficientes beta estandarizados de regresión cuantil?

Es posible interpretar los coeficientes de una regresión cuantil de datos normalizados?

Supongamos que yo estandarizar la variable dependiente $y$ y la variable independiente $x$ (restar la media y dividir por la desviación estándar) y, a continuación, ejecutar una regresión cuantil para la mediana como

qreg y x, q(0.5) 

en stata. El coeficiente estimado para la variable independiente es $0.5$. Es entonces la siguiente interpretación correcta:

Un aumento de una desviación estándar de la variable independiente aumenta la mediana de la variable dependiente por $0.5$ desviación estándar?

3voto

RGA Puntos 113

Sí, esa es la interpretación. Una manera en la que usted puede ver que esto es por la predicción de la mediana para los diferentes valores de su estandarizado, cada uno de 1 unidad (en este caso la desviación estándar) appart. Lo que usted puede ver lo mucho que estos predijo que las medianas son diferentes, y verás que es exactamente el mismo número que su estandarizado cuantil coeficiente de regresión. He aquí un ejemplo:

. sysuse auto, clear
(1978 Automobile Data)

. 
. // standardize variables
. sum price if !missing(price,weight)

    Variable |       Obs        Mean    Std. Dev.       Min        Max
-------------+--------------------------------------------------------
       price |        74    6165.257    2949.496       3291      15906

. gen double z_price = ( price - r(mean) ) / r(sd)

. 
. sum weight if !missing(price,weight)

    Variable |       Obs        Mean    Std. Dev.       Min        Max
-------------+--------------------------------------------------------
      weight |        74    3019.459    777.1936       1760       4840

. gen double z_weight = ( weight - r(mean) ) / r(sd)

. 
. // estimate the quartile regression
. qreg z_price z_weight
Iteration  1:  WLS sum of weighted deviations =  47.263794

Iteration  1: sum of abs. weighted deviations =  54.018868
Iteration  2: sum of abs. weighted deviations =  43.851751

Median regression                                    Number of obs =        74
  Raw sum of deviations 48.21332 (about -.41744651)
  Min sum of deviations 43.85175                     Pseudo R2     =    0.0905

------------------------------------------------------------------------------
     z_price |      Coef.   Std. Err.      t    P>|t|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
    z_weight |   .2552875   .1368752     1.87   0.066    -.0175682    .5281432
       _cons |  -.3415908   .1359472    -2.51   0.014    -.6125966    -.070585
------------------------------------------------------------------------------

. 
. // predict the predicted median for z_weight
. // is -2, -1, 0, 1, 2
. drop _all

. set obs 5
obs was 0, now 5

. gen z_weight = _n - 3

. predict med
(option xb assumed; fitted values)

. list

     +----------------------+
     | z_weight         med |
     |----------------------|
  1. |       -2   -.8521658 |
  2. |       -1   -.5968783 |
  3. |        0   -.3415908 |
  4. |        1   -.0863033 |
  5. |        2    .1689841 |
     +----------------------+

. 
. // compute how much the predicted median
. // differs between cars 1 standard deviation
. // weight apart
. gen diff = med - med[_n - 1]
(1 missing value generated)

. list

     +---------------------------------+
     | z_weight         med       diff |
     |---------------------------------|
  1. |       -2   -.8521658          . |
  2. |       -1   -.5968783   .2552875 |
  3. |        0   -.3415908   .2552875 |
  4. |        1   -.0863033   .2552875 |
  5. |        2    .1689841   .2552875 |
     +---------------------------------+

i-Ciencias.com

I-Ciencias es una comunidad de estudiantes y amantes de la ciencia en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: